TextField.StyleSheet.clear()

Доступность

Flash Player 7.

Синтаксис

styleSheet.clear() : Void

Параметры

Нет.

Возвращает

Ничего.

Описание

Метод; Удаляет все стили объекта таблиц стиля.

Пример

В следующем примере загружается таблица стиля определённая в styles.css в файл SWF , и в панели Output выводятся стили, которые были загружены. Когда Вы нажимаете clear_btn, все стили объекта my_styleSheet удиляются :

// Создаётся новый объект таблиц стиля
var my_styleSheet:TextField.StyleSheet = new TextField.StyleSheet();
my_styleSheet.onLoad = function(success:Boolean) {
  if (success) {
    trace("Styles loaded.");
    var styles_array:Array = my_styleSheet.getStyleNames();
    for (var i = 0; i<styles_array.length; i++) {
      trace("\t"+styles_array[i]);
    }
    trace("");
  } else {
    trace("Error loading CSS");
  }
};

// Начало операции загрузки
my_styleSheet.load("styles.css");

clear_btn.onRelease = function() {
  my_styleSheet.clear();
  trace("Styles cleared.");
  var styles_array:Array = my_styleSheet.getStyleNames();
  for (var i = 0; i<styles_array.length; i++) {
    trace("\t"+styles_array[i]);
  }
  trace("");
};

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление